EnigmA Amiga Run 1997 April/EnigmA AMIGA RUN 17 (1997)(G.R. Edizioni)(IT)[!][issue 1997-04][EAR-CD].iso/EARCD/comm/misc/zpoint_3_14.lha/zpoint-3.14/Rexx/Weiterleiten.zprx

Text File | 1996-03-04 | 5KB | 211 lines

/* $VER: Weiterleiten.zprx 1.2 (2.3.1996), ©95 Jean-Marie de Crozals

  COPYRIGHT
   Dieses  ARexx-Skript  ist  FD.  Änderungen  sind  nur  im   Rahmen   der
   Konfiguration  dieses  Skriptes  oder  der  Anpassung  an neue "Zodiac's
   Point"-Versionen zulässig. Die kommerzielle  Verwendung  ist  untersagt.
   Ausnahme  ist  die Hinzufügung zu dem Programmpaket "Zodiac's Point" von
   Ralph Seichter.

  INSTALLATION
   Man kann dieses Script wie folgt auf eine F-Taste legen...
   F1:SYS:RexxC/Rx ZPOINT:Rexx/Weiterleiten.zprx %s

   WICHTIG: Diese Skript benötigt UNBEDINGT folgende Library:

   - rexxtricks.library
   - reqrexxtools.library

  BESCHREIBUNG
   Dieses Script leitet die markierten Nachrichten in beliebige Bretter
   (außer Spool-Brett) weiter... Die markierten Nachrichten werden
   in diesem Brett gelöscht...
*/

/*
  folgende Änderungen wurden von mir, Nils Görs, durchgeführt.
  Das Copyright liegt aber weiterhin bei Jean-Marie de Crozals.

  + das Weiterleiten in das Nachrichtenarchiv.
  + die Anpassung an die rexxtricks.library V38.2.
  + bessere und schnellere Mehode zum weiterleiten.
  + Nachrichten können zum löschen bzw. zum reorganisieren markiert
    werden.
  + alias.zp wird nun auch unterstützt (externes weiterleiten!)
  + externes Weiterleiten über Brettgrenzen hinweg.
  + beim externen Weiterleiten wird die Nachricht nun ggf. als
    Crossposting versendet.
*/

NL = '0a'x

OPTIONS RESULTS

/* ------ von welchem ZP Port wurde das Script aufgerufen ? ------ */
PARSE ARG zpPort
IF zpPort == "" THEN
   zpPort = "ZPoint"
ADDRESS VALUE zpPort

if (~show('LIBRARIES', 'rexxreqtools.library')) then
 if (~addlib('rexxreqtools.library', 0, -30, 0)) then
  do
   REQUESTNOTIFY 'Kann rexxreqtools.library nicht öffnen!'
   exit
 end

if (~show('LIBRARIES', 'rexxtricks.library')) then
 if (~addlib('rexxtricks.library', 0, -30, 0)) then
  do
   REQUESTNOTIFY 'Kann rexxtricks.library nicht öffnen!'
   exit
 end

WHICHLEVEL
if (result ~= 'BOARD') then
 do
  REQUESTNOTIFY 'Du mußt schon in ein Brett gehen!!!'
  exit
 end

COUNT LISTED
IF RESULT == 0 THEN SELECTMESSAGE

HOMEPATH
Heimatpfad = result
BrettListe = Heimatpfad'/boardlist.zp'
UserListe  = Heimatpfad'/alias.zp'

'GUILOCK text="Bitte haben Sie etwas Geduld!"'

COUNT ALL
Anzahl = result

if (~open('Bretter',BrettListe,'R')) then
 do
  REQUESTNOTIFY 'Kann Brettliste nicht laden!'
  exit
 end

i=1
liste.i = 'Nachrichtenarchiv'
i=i+1
do forever
 Zeile = readln('Bretter')
 if Zeile='' then leave
 if left(Zeile,2)='B:' then
  do
   Laenge = length(Zeile)-2
   Zeile = right(Zeile,Laenge)
   liste.i = Zeile
   i = i+1
  end
end
call CLOSE('Bretter')
liste.0 = i-1

if ~open(User,Userliste,'R') then
 do
  REQUESTNOTIFY 'Kann aliasliste nicht laden!'
  exit
 end

i=1
user.i = '   ----- Userliste -----'
i=i+1
do while ~EOF(User)
 Zeile = readln(User)
 if left(Zeile,2)='A:' then
  do
   Laenge = length(Zeile)-2
   Zeile = right(Zeile,Laenge)
   user.i = Zeile
   i = i+1
  end
end
call CLOSE(User)
user.0 = i-1
call QSORT(user,,)

i = liste.0
internmarker = liste.0
i =i+1
DO a = 1 to user.0
liste.i = user.a
i =i+1
END
liste.0 = liste.0+user.0

fenster.title      = 'Zielbrett wählen...'
fenster.pubscreen  = zpPort
fenster.gadgettext = 'extern _Weiterleiten|_interne Kopie|_Abbruch'
fenster.width      = 600
fenster.font       = 'SCREEN'
fenster.sort       = 'FALSE'

if (~VIEWLIST('liste','fenster','destvar')) THEN DO
  GUILOCK OFF
  exit
END

CALL rtezrequest("Was soll mit den Nachrichten passieren?",,
                 "nicht löschen|zum _löschen markieren|zum _reorganisieren markieren",,
                 "Weiterleiten","rt_pubscrname="zpPort)
WhatToDo = RESULT

CALL TIME('Reset')

Messages = 0
more= 1
j = 1
 JUMPTOMESSAGE 1
  MESSAGEINFO LISTED
  IF Result == 1 THEN CALL _Weiterleiten

DO WHILE more
  JUMPTOMESSAGE LISTED
  more = (RC)
 IF more == 1 THEN CALL _Weiterleiten
END

STime = TIME('Elapsed')
Messages = Messages/destvar.0
REQUESTNOTIFY "Es wurden" Messages "Nachrichten in" destvar.0 "Bretter weitergeleitet!",
            NL"Diese Transaktion hat" STime "sek. gedauert!"
EXIT

/*********************************************
 *** Nachricht in die Bretter weiterleiten ***
 *********************************************/
_Weiterleiten:
IF destvar.gadget == 1 THEN DO
  DO k = 1 to destvar.0
   BrettName = BrettName||","||destvar.k
  END
  BrettName = DELSTR(BrettName,1,10)
  FORWARDMESSAGE RECEIVER '"'BrettName'"'
  IF messages == 0 THEN Messages = 1
  Messages = Messages * 2
 END

ELSE DO
  DO j = 1 to destvar.0
   BrettName = destvar.j
   FORWARDMESSAGE '"'BrettName'" INTERNAL'
   Messages = Messages + 1
  END
END

 SELECT        /* Was soll danach mit den Nachrichten passieren? */
   WHEN WhatToDo == 1 THEN NOP
   WHEN WhatToDo == 2 THEN DELETE ONE
   WHEN WhatToDo == 0 THEN DELETE LATER ONE
 OTHERWISE
   NOP
 END

DROP Brettname

RETURN
/*EOS*/